10 REM  COPYRIGHT 1985
20 REM  ALL RIGHTS RESERVED.
30 !   *********************
40 !   * KENNETH FINTO     *       * PROGRAMMER        *       * ROUTE 2 BOX 44    *       * ROSEBUD TX 76570  *
50 !   *                   *       * GENIE ADDRESS:    *       * KEN.FINTO         *       *********************
60 CALL MAGNIFY(3)
70 DIM CONDITION$(28)
80 CALL CLEAR
90 DISPLAY AT(7,7):"MISSILE DEFENSE"
100 DISPLAY AT(9,13):"BY"
110 DISPLAY AT(11,8):"KENNETH FINTO"
120 DISPLAY AT(22,7):"COPYRIGHT 1985"
130 DISPLAY AT(24,4)BEEP :"ALL RIGHTS RESERVED."
140 FOR DELAY=1 TO 200 :: NEXT DELAY
150 MS=0 :: CD=128
160 FOR X=1 TO 19
170 IF X<>15 THEN 290 ELSE CALL CLEAR :: DISPLAY AT(12,1)BEEP :"INSTRUCTIONS?": :"YES, PRESS FIREBUTTON":"NO,  PRESS JOYSTICK DOWN"
180 CALL KEY(1,K,S) :: CALL JOYST(1,JOYX,JOYY) :: IF JOYY=-4 THEN DISPLAY AT(12,1)ERASE ALL :"     ONE MOMENT PLEASE" :: GOTO 290
190 IF K=18 THEN 200 ELSE 180
200 DISPLAY AT(2,1)ERASE ALL :"IN MISSILE DEFENSE, YOU MUST": :"PROTECT YOUR CITIES FROM THE": :"ENEMY PLANES, BOMBS, AND": :"MISSILES. YOUR ONLY DEFENSE"
210 DISPLAY AT(10,1):"IS YOUR GROUND-TO-AIR MIS-": :"SILE DEFENSE SYSTEM. TO OP-": :"ERATE THE SYSTEM USE JOY-": :"STICK #1 TO CONTROL THE": :"CROSSHAIR AND PRESS THE"
220 DISPLAY AT(20,1):"FIREBUTTON TO EXPLODE A" :: DISPLAY AT(23,1)BEEP :"PRESS FIREBUTTON TO CONTINUE"
230 CALL KEY(1,K,S) :: IF K=18 THEN 240 ELSE 230
240 DISPLAY AT(2,1)ERASE ALL :"MISSILE. THE ENEMY'S WEAP-": :"ONS ARE OLD, SO SOME MIS-": :"SILES THAT HIT YOUR CITIES": :"MIGHT NOT EXPLODE. THE GAME"
250 DISPLAY AT(10,1):"ENDS WHEN YOU RUN OUT OF": :"MISSILES OR WHEN ALL OF YOUR": :"CITIES ARE DESTROYED. YOU": :"ARE AWARDED BONUS POINTS AND"
260 DISPLAY AT(18,1):"MISSILES FOR EACH REMAINING": :"CITY ON EACH SCREEN." :: DISPLAY AT(23,1)BEEP :"PRESS FIREBUTTON TO BEGIN."
270 CALL KEY(1,K,S) :: IF K=18 THEN 280 ELSE 270
280 DISPLAY AT(23,1)BEEP :"    ONE MOMENT PLEASE."
290 READ A,A$
300 CALL CHAR(A,A$)
310 NEXT X
320 DATA 132,80C0FCFF3C000000000000000000000000000000000000000000000000000000
330 DATA 128,FFFFFFFFFFFFFFFF,112,181818FFFF181818000000000000000000000000000000000000000000000000
340 DATA 116,0000000800000000000000000000000000000000000000000000000000000000
350 DATA 109,00080808081C0000,97,808080808040201F
360 DATA 98,01010101010204F8,99,8080808080808080
370 DATA 100,0101010101010101,101,1010101010204080
380 DATA 102,0808080808040201,103,FF00000000000000
390 DATA 104,00000000000000FF,120,AAFFAAFFAAFFAAFF
400 DATA 105,8000000000000000,106,0000000000000080
410 DATA 107,0100000000000000,108,0000000000000001
420 DATA 124,00031F3F7F7FFFFF7F7F3F3F0F0701000080F8FCFFFFFFFEFEFEFCFCF8C000
430 FOR X=1 TO 14 :: CALL COLOR(X,1,1) :: NEXT X
440 CALL HCHAR(1,1,32,640) :: CALL HCHAR(21,1,128,128)
450 CALL HCHAR(18,9,120) :: CALL HCHAR(18,20,120) :: CALL HCHAR(18,22,120)
460 CALL HCHAR(19,3,120) :: CALL HCHAR(19,8,120,2) :: CALL HCHAR(19,11,120) :: CALL HCHAR(19,20,120,4) :: CALL HCHAR(19,30,120)
470 CALL HCHAR(20,2,120,2) :: CALL HCHAR(20,8,120,5) :: CALL HCHAR(20,19,120,5) :: CALL HCHAR(20,30,120,2)
480 CALL VCHAR(18,2,120,2) :: CALL VCHAR(19,4,120,2) :: CALL VCHAR(19,29,120,2) :: CALL HCHAR(18,30,120)
490 CALL HCHAR(21,3,108) :: CALL VCHAR(22,3,100,2) :: CALL HCHAR(24,3,107)
500 CALL HCHAR(21,30,106) :: CALL VCHAR(22,30,99,2) :: CALL HCHAR(24,30,105)
510 DISPLAY AT(21,2)SIZE(2):"hb" :: DISPLAY AT(21,5)SIZE(3):"ahj" :: DISPLAY AT(21,11)SIZE(8):"lhhefhhj"
520 DISPLAY AT(21,22)SIZE(3):"lhb" :: DISPLAY AT(21,26)SIZE(3):"ahj"
530 DISPLAY AT(22,2)SIZE(6):"mmmmmc" :: DISPLAY AT(22,11)SIZE(8):"dmmmmmmc" :: DISPLAY AT(22,22)SIZE(6):"dmmmmm"
540 DISPLAY AT(23,2)SIZE(6):"mmmmmc" :: DISPLAY AT(23,11)SIZE(8):"dmmmmmmc" :: DISPLAY AT(23,22)SIZE(6):"dmmmmm"
550 DISPLAY AT(24,2)SIZE(6):"gggggi" :: DISPLAY AT(24,11)SIZE(8):"kggggggi" :: DISPLAY AT(24,22)SIZE(6):"kggggg"
560 SCORE=0
570 DISPLAY AT(2,1):"SCORE =" :: DISPLAY AT(2,8):SCORE
580 CALL SCREEN(5)
590 FOR X=1 TO 8 :: CALL COLOR(X,16,5) :: NEXT X
600 CALL COLOR(9,2,16) :: CALL COLOR(10,2,16)
610 CALL COLOR(12,15,2)
620 CALL COLOR(13,16,16)
630 CALL SPRITE(#1,112,16,89,121,0,0)
640 NUMOFM=9
650 LEVEL=LEVEL+1
660 IF LEVEL>0 THEN SPEED=1
670 IF NUMOFM=14 THEN NUMOFM=10 ELSE NUMOFM=NUMOFM+1
680 IF LEVEL>5 THEN NUMOFM=14
690 IF LEVEL>6 THEN NUMOFM=13
700 IF LEVEL>10 THEN NUMOFM=10 :: SPEED=2
710 IF LEVEL>13 THEN NUMOFM=12
720 T=0
730 RANDOMIZE
740 C=-1 :: COUNT=NUMOFM-6
750 FOR B=7 TO NUMOFM
760 ROWVEL=SPEED
770 COLVEL=INT(RND*-6)+4
780 C=C+(17-NUMOFM)
790 C=MAX(C,7)
800 C=MIN(C,250)
810 CALL SPRITE(#B,116,16,17,8*C-7,ROWVEL,COLVEL)
820 CONDITION$(B)="ON"
830 NEXT B
840 N=B+4
850 CALL SPRITE(#3,132,16,41,8,0,SPEED*2) :: COUNT=COUNT+1 :: CONDITION$(3)="ON"
860 IF LEVEL>3 THEN CALL SPRITE(#4,132,16,65,65,0,SPEED*2) :: COUNT=COUNT+1 :: CONDITION$(4)="ON"
870 IF LEVEL>6 THEN CALL SPRITE(#5,132,16,89,121,0,SPEED*2) :: COUNT=COUNT+1 :: CONDITION$(5)="ON"
880 IF LEVEL>9 THEN CALL SPRITE(#6,132,16,113,177,0,SPEED*2) :: COUNT=COUNT+1 :: CONDITION$(6)="ON"
890 GOSUB 920
900 GOTO 1840
910 ! joystick routine
920 CALL JOYST(1,XX,YY) :: CALL KEY(1,K,S)
930 XX=XX*2 :: YY=-YY*2
940 CALL POSITION(#1,YYY,XXX)
950 IF XX=0 AND YY=0 AND K<>18 THEN CALL MOTION(#1,0,0) :: RETURN
960 IF YYY<=25 AND YY=8 THEN CALL MOTION(#1,YY,XX)ELSE IF YYY<=25 AND YY<>8 THEN CALL MOTION(#1,0,XX) :: GOTO 990
970 IF YYY>=120 AND YY=-8 THEN CALL MOTION(#1,YY,XX)ELSE IF YYY>=120 AND YY<>-8 THEN CALL MOTION(#1,0,XX)
980 IF YYY>25 AND YYY<120 THEN CALL MOTION(#1,YY,XX)
990 CALL KEY(1,K,S)
1000 IF K=18 THEN 1010 ELSE 1230
1010 MS=MS+1
1020 ON MS GOSUB 1240,1250,1260,1270,1280,1290,1300,1310,1320,1330,1340,1350,1360,1370,1380,1390,1400,1410,1420,1430,1440,1450,1460,1470,1480,1490,1500,1510,1520,1530,1540,1550
1030 ! check for hit routine
1040 CALL POSITION(#1,R,C)
1050 CALL MOTION(#1,0,0)
1060 R=MAX(R,6)
1070 C=MAX(C,6)
1080 CALL SPRITE(#2,124,16,R-5,C-5,0,0)
1090 SO=0
1100 FOR CH=3 TO N
1110 IF CONDITION$(CH)="ON" THEN 1120 ELSE 1180
1120 CALL COINC(#2,#CH,10,CFH)
1130 IF CFH THEN CALL SOUND(1000,-7,0) :: CALL DELSPRITE(#CH) :: SCORE=SCORE+10 :: DISPLAY AT(2,8):SCORE :: T=T+1 :: SO=1 :: CONDITION$(CH)="OFF" :: IF T=COUNT THEN 1560
1140 CALL POSITION(#CH,R,C)
1150 IF R>161 THEN CALL DELSPRITE(#CH) :: CONDITION$(CH)="OFF" :: T=T+1 :: IF T=COUNT THEN 1560
1160 IF R>120 AND CONDITION$(CH)="ON" THEN CHFORB=1 :: CHB=CH :: GOTO 1870
1170 CHFORB=0
1180 NEXT CH
1190 IF SO=0 THEN CALL SOUND(1000,-7,0)
1200 CALL DELSPRITE(#2)
1210 IF T=COUNT THEN 1560
1220 IF MS=32 THEN 2210
1230 RETURN
1240 DISPLAY AT(22,2)SIZE(1):CHR$(CD) :: RETURN
1250 DISPLAY AT(23,2)SIZE(1):CHR$(CD) :: RETURN
1260 DISPLAY AT(22,3)SIZE(1):CHR$(CD) :: RETURN
1270 DISPLAY AT(23,3)SIZE(1):CHR$(CD) :: RETURN
1280 DISPLAY AT(22,4)SIZE(1):CHR$(CD) :: RETURN
1290 DISPLAY AT(23,4)SIZE(1):CHR$(CD) :: RETURN
1300 DISPLAY AT(22,5)SIZE(1):CHR$(CD) :: RETURN
1310 DISPLAY AT(23,5)SIZE(1):CHR$(CD) :: RETURN
1320 DISPLAY AT(22,6)SIZE(1):CHR$(CD) :: RETURN
1330 DISPLAY AT(23,6)SIZE(1):CHR$(CD) :: RETURN
1340 DISPLAY AT(22,12)SIZE(1):CHR$(CD) :: RETURN
1350 DISPLAY AT(23,12)SIZE(1):CHR$(CD) :: RETURN
1360 DISPLAY AT(22,13)SIZE(1):CHR$(CD) :: RETURN
1370 DISPLAY AT(23,13)SIZE(1):CHR$(CD) :: RETURN
1380 DISPLAY AT(22,14)SIZE(1):CHR$(CD) :: RETURN
1390 DISPLAY AT(23,14)SIZE(1):CHR$(CD) :: RETURN
1400 DISPLAY AT(22,15)SIZE(1):CHR$(CD) :: RETURN
1410 DISPLAY AT(23,15)SIZE(1):CHR$(CD) :: RETURN
1420 DISPLAY AT(22,16)SIZE(1):CHR$(CD) :: RETURN
1430 DISPLAY AT(23,16)SIZE(1):CHR$(CD) :: RETURN
1440 DISPLAY AT(22,17)SIZE(1):CHR$(CD) :: RETURN
1450 DISPLAY AT(23,17)SIZE(1):CHR$(CD) :: RETURN
1460 DISPLAY AT(22,23)SIZE(1):CHR$(CD) :: RETURN
1470 DISPLAY AT(23,23)SIZE(1):CHR$(CD) :: RETURN
1480 DISPLAY AT(22,24)SIZE(1):CHR$(CD) :: RETURN
1490 DISPLAY AT(23,24)SIZE(1):CHR$(CD) :: RETURN
1500 DISPLAY AT(22,25)SIZE(1):CHR$(CD) :: RETURN
1510 DISPLAY AT(23,25)SIZE(1):CHR$(CD) :: RETURN
1520 DISPLAY AT(22,26)SIZE(1):CHR$(CD) :: RETURN
1530 DISPLAY AT(23,26)SIZE(1):CHR$(CD) :: RETURN
1540 DISPLAY AT(22,27)SIZE(1):CHR$(CD) :: RETURN
1550 DISPLAY AT(23,27)SIZE(1):CHR$(CD) :: RETURN
1560 CD=109
1570 CALL MOTION(#1,0,0) :: CALL DELSPRITE(#2)
1580 IF LEVEL>0 THEN 1590 ELSE 1600
1590 BM=3*(4-DC)
1600 IF LEVEL>3 THEN 1610 ELSE 1620
1610 BM=4*(4-DC)
1620 IF LEVEL>6 THEN 1630 ELSE 1640
1630 BM=5*(4-DC)
1640 IF LEVEL>9 THEN 1650 ELSE 1660
1650 BM=6*(4-DC)
1660 IF LEVEL>15 THEN 1670 ELSE 1680
1670 BM=7*(4-DC)
1680 RM=MAX(MS,0) :: RM=MIN(MS,32)
1690 BMM=BM-MS
1700 IF BMM>0 THEN BM=MS
1710 DISPLAY AT(7,4):"END OF SCREEN" :: DISPLAY AT(7,21):USING 1760:LEVEL
1720 DISPLAY AT(8,4):"BONUS POINTS" :: DISPLAY AT(8,21):USING 1760:LEVEL*10*(4-DC)
1730 DISPLAY AT(9,4):"BONUS MISSILES" :: DISPLAY AT(9,21):USING 1760:BM
1740 SCORE=SCORE+(LEVEL*10*(4-DC)) :: DISPLAY AT(2,8):SCORE
1750 RM=RM+1 :: BM=BM+1
1760 IMAGE "######"
1770 RM=RM-1 :: BM=BM-1
1780 IF RM=0 OR BM=0 THEN 1790 ELSE 1810
1790 FOR DELAY=1 TO 1000 :: NEXT DELAY
1800 MS=MAX(RM,0) :: CD=128 :: DISPLAY AT(7,1):"" :: DISPLAY AT(8,1):"" :: DISPLAY AT(9,1):"" :: GOTO 650
1810 CALL SOUND(100,1000,0)
1820 ON RM GOSUB 1240,1250,1260,1270,1280,1290,1300,1310,1320,1330,1340,1350,1360,1370,1380,1390,1400,1410,1420,1430,1440,1450,1460,1470,1480,1490,1500,1510,1520,1530,1540,1550
1830 GOTO 1770
1840 CHB=7
1850 CALL POSITION(#CHB,R,C)
1860 IF R>161 THEN CALL DELSPRITE(#CHB) :: CONDITION$(CHB)="OFF" :: T=T+1 :: IF T=COUNT THEN 1560 ELSE 2040
1870 IF D1=1 THEN 1910 ELSE IF R>120 AND(C>9 AND C<33)THEN 1880 ELSE 1910
1880 CALL SPRITE(#2,124,16,145,17) :: CALL SOUND(1000,-7,0)
1890 D1=1 :: CALL DELSPRITE(#CHB) :: DISPLAY AT(18,1)SIZE(2):"" :: DISPLAY AT(19,1)SIZE(2):"" :: DISPLAY AT(20,1)SIZE(2):"" :: CALL VCHAR(18,2,32,3)
1900 CALL DELSPRITE(#2) :: CONDITION$(CHB)="OFF" :: DC=DC+1 :: T=T+1 :: IF DC=4 THEN 2210
1910 IF D2=1 THEN 1950 ELSE IF R>120 AND(C>57 AND C<89)THEN 1920 ELSE 1950
1920 CALL SPRITE(#2,124,16,145,73) :: CALL SOUND(1000,-7,0)
1930 D2=1 :: CALL DELSPRITE(#CHB) :: DISPLAY AT(18,7)SIZE(1):"" :: DISPLAY AT(19,6)SIZE(4):"" :: DISPLAY AT(20,6)SIZE(5):"" :: DC=DC+1 :: T=T+1 :: CALL DELSPRITE(#2)
1940 CONDITION$(CHB)="OFF" :: IF DC=4 THEN 2210
1950 IF D3=1 THEN 1990 ELSE IF R>120 AND(C>145 AND C<177)THEN 1960 ELSE 1990
1960 CALL SPRITE(#2,124,16,145,161) :: CALL SOUND(1000,-7,0)
1970 D3=1 :: CALL DELSPRITE(#CHB) :: DISPLAY AT(18,18)SIZE(3):"" :: DISPLAY AT(19,18)SIZE(4):"" :: DISPLAY AT(20,17)SIZE(5):"" :: DC=DC+1 :: T=T+1 :: CALL DELSPRITE(#2)
1980 CONDITION$(CHB)="OFF" :: IF DC=4 THEN 2210
1990 IF D4=1 THEN 2030 ELSE IF R>120 AND(C>225 AND C<249)THEN 2000 ELSE 2030
2000 CALL SPRITE(#2,124,16,145,233) :: CALL SOUND(1000,-7,0)
2010 D4=1 :: CALL DELSPRITE(#CHB) :: DISPLAY AT(18,27)SIZE(2):"" :: DISPLAY AT(19,27)SIZE(2):"" :: DISPLAY AT(20,27)SIZE(2):"" :: CALL HCHAR(20,31,32) :: CALL DELSPRITE(#2)
2020 CONDITION$(CHB)="OFF" :: DC=DC+1 :: T=T+1 :: IF DC=4 THEN 2210
2030 IF CHFORB=1 THEN 1170
2040 GOSUB 920
2050 CHB=CHB+1
2060 IF CHB=N+1 THEN 2070 ELSE 1850
2070 IF T=COUNT THEN 1560
2080 FOR CPP=3 TO 7
2090 IF CONDITION$(CPP)="ON" THEN CALL POSITION(#CPP,RP,CP) :: IF RP>0 AND CP>0 THEN 2100 ELSE 2180 :: ELSE 2180
2100 IF CP>7 AND CP<35 THEN 2150
2110 IF CP>60 AND CP<105 THEN 2150
2120 IF CP>140 AND CP<180 THEN 2150
2130 IF CP>210 AND CP<250 THEN 2150
2140 GOTO 2180
2150 FOR CCOB=7 TO N
2160 IF CONDITION$(CCOB)="OFF" THEN CALL SPRITE(#CCOB,116,16,RP,CP,SPEED,0) :: CONDITION$(CCOB)="ON" :: CCOB=28 :: COUNT=COUNT+1
2170 NEXT CCOB
2180 GOSUB 920
2190 NEXT CPP
2200 GOTO 1840
2210 CALL DELSPRITE(ALL) :: IF MS=32 THEN DISPLAY AT(11,1):"OUT OF MISSILES-NO DEFENSE. THE ENEMY WILL NOW TAKE OVERTHE LAST REMNANTS OF YOUR   COUNTRY---GAME OVER." :: GOTO 2230
2220 DISPLAY AT(11,1):"YOUR COUNTRY HAS BEEN       TOTALLY DESTROYED BY THE    ENEMY---GAME OVER."
2230 FOR X=1 TO 1000 :: NEXT X
2240 SD=0 :: CALL CLEAR
2250 DISPLAY AT(3,8):"HIGH SCORES"
2260 IF SCORE>=HGHSCORE1 THEN HGHSCORE5=HGHSCORE4 :: HGHSCORE4=HGHSCORE3 :: HGHSCORE3=HGHSCORE2 :: HGHSCORE2=HGHSCORE1 :: HGHSCORE1=SCORE
2270 IF SCORE>=HGHSCORE1 THEN 2280 ELSE 2290
2280 NAME5$=NAME4$ :: NAME4$=NAME3$ :: NAME3$=NAME2$ :: NAME2$=NAME1$ :: NAME1$="" :: SD=5 :: GOTO 2370
2290 IF SCORE>=HGHSCORE2 THEN HGHSCORE5=HGHSCORE4 :: HGHSCORE4=HGHSCORE3 :: HGHSCORE3=HGHSCORE2 :: HGHSCORE2=SCORE
2300 IF SCORE>=HGHSCORE2 THEN 2310 ELSE 2320
2310 NAME5$=NAME4$ :: NAME4$=NAME3$ :: NAME3$=NAME2$ :: NAME2$="" :: SD=6 :: GOTO 2370
2320 IF SCORE>=HGHSCORE3 THEN HGHSCORE5=HGHSCORE4 :: HGHSCORE4=HGHSCORE3 :: HGHSCORE3=SCORE
2330 IF SCORE>=HGHSCORE3 THEN 2340 ELSE 2350
2340 NAME5$=NAME4$ :: NAME4$=NAME3$ :: NAME3$="" :: SD=7 :: GOTO 2370
2350 IF SCORE>=HGHSCORE4 THEN HGHSCORE5=HGHSCORE4 :: HGHSCORE4=SCORE :: NAME5$=NAME4$ :: NAME4$="" :: SD=8 :: GOTO 2370
2360 IF SCORE>=HGHSCORE5 THEN HGHSCORE5=SCORE :: NAME5$="" :: SD=9
2370 DISPLAY AT(5,7):USING 2690:HGHSCORE1 :: DISPLAY AT(5,17):NAME1$
2380 DISPLAY AT(6,7):USING 2690:HGHSCORE2 :: DISPLAY AT(6,17):NAME2$
2390 DISPLAY AT(7,7):USING 2690:HGHSCORE3 :: DISPLAY AT(7,17):NAME3$
2400 DISPLAY AT(8,7):USING 2690:HGHSCORE4 :: DISPLAY AT(8,17):NAME4$
2410 DISPLAY AT(9,7):USING 2690:HGHSCORE5 :: DISPLAY AT(9,17):NAME5$
2420 IF SCORE<HGHSCORE5 THEN 2600
2430 IF SD THEN DISPLAY AT(11,1)BEEP :"ENTER YOUR INITIAL'S BY":"MOVING THE JOYSTICK UP OR":"DOWN. PRESS FIRE WHEN YOU":"FIND THE LETTER YOU NEED."
2440 CS=19 :: CTD=32
2450 IF SD THEN CALL HCHAR(SD,CS,CTD)
2460 CALL JOYST(1,XX,YY) :: CALL KEY(1,K,S)
2470 IF XX=0 AND YY=-4 THEN CTD=CTD+1 :: IF CTD>90 THEN CTD=32 ELSE IF CTD<40 AND CTD>32 THEN CTD=65
2480 IF XX=0 AND YY=4 THEN CTD=CTD-1 :: IF CTD<65 AND CTD>50 THEN CTD=32 ELSE IF CTD>1 AND CTD<32 THEN CTD=90
2490 IF K=18 THEN DISPLAY AT(22,22)SIZE(1)BEEP :"" ELSE 2450
2500 IF CS=19 THEN CALL GCHAR(SD,CS,AX) :: A$=CHR$(AX)
2510 IF CS=20 THEN CALL GCHAR(SD,CS,BX) :: B$=CHR$(BX)
2520 IF CS=21 THEN CALL GCHAR(SD,CS,CX) :: C$=CHR$(CX)
2530 IF SD=5 THEN NAME1$=A$&B$&C$
2540 IF SD=6 THEN NAME2$=A$&B$&C$
2550 IF SD=7 THEN NAME3$=A$&B$&C$
2560 IF SD=8 THEN NAME4$=A$&B$&C$
2570 IF SD=9 THEN NAME5$=A$&B$&C$
2580 CS=CS+1 :: CTD=32
2590 IF CS=22 THEN 2600 ELSE 2450
2600 DISPLAY AT(11,1)BEEP :"PLAY AGAIN?":"YES, PRESS JOYSTICK DOWN.":"NO,  PRESS FIREBUTTON.":""
2610 CALL JOYST(1,XX,YY) :: CALL KEY(1,K,S)
2620 IF XX=0 AND YY=-4 THEN MS,D1,D2,D3,D4,DC,LEVEL,T,COUNT=0 ELSE 2670
2630 FOR CONDIT=1 TO 28
2640 CONDITION$(CONDIT)="OFF"
2650 NEXT CONDIT
2660 GOTO 430
2670 IF K=18 THEN 2680 ELSE 2610
2680 CALL CLEAR
2690 IMAGE "#########"
2700 END
